#
# +taxi/+dir
#
# Last updated by gossamer on Sat Jan 24 09:58:20 EST 1998
#

#
# Change these as appropriate:
#    Directory Object = #1516
#    Directory Data Object = #1498
#

#
# You'll need to set the Directory Object INHERIT.
#

&CMD-TAXI #1516=
   $+taxi:
      @pemit %#=Where do you want to go?  Try +dir for a list.

&CMD-TAXI #1516=
   $+taxi *:
      @switch [setq(0,get(#1498/LOC-%0))]%q0=
         ?*,
            {
               @pemit %#=Broom Broom ...;
               @tel %#=[before(%q0,|)]
            },
         {
            @pemit %#=Sorry, I don't know that place.  Try +dir for a list.
         }

&CMD-TAXI-HELP #1516=
   $+taxi/help:
      @pemit %#=
         [repeat(-,72)]%r
         +taxi <placename> - Takes you direct to a place listed in +dir%r
         %r
         See also +dir/help.%r%r
         Coded by Charade@SYE.%r
         [repeat(-,72)]

&CMD-DIR-HELP #1516=
   $+dir/help:
      @pemit %#=
         [repeat(-,72)]%r
         +dir <placename> - List the name and grid intersection of a specific place%r
         +dir - List all places%r
         %r
         +dir/add <placeabbrev>/#<dbnum>=<placename> - Add a new place to the list (staff only)%r
         %r
         See also +taxi/help.%r%r
         Coded by Charade@SYE.%r
         [repeat(-,72)]

&CMD-DIR-ADD #1516=
   $+dir/add */*=*:
      @switch [hasflag(%#,WIZARD)]/[type(%1)]=
         0/*,
            {
               @pemit %#=Sorry, only staff can add places to the +dir list, please ask a staffmember.
            },
         1/ROOM,
            {
               &LOC-%0 #1498=%1|%2;
               @pemit %#=You have added '%2' (%1) to the +dir/+taxi list with abbreviation [ucstr(%0)].
            },
         {
            @pemit %#=Sorry, '%1' does not appear to be a valid room dbref.
         }

&CMD-DIR #1516=
   $+dir:
      @pemit %#=
         [repeat(-,72)]%r
         Directory Listing for +taxi/+dir:
         [map(#1498/fn-display-dir-entry,lattr(#1498/loc-*))]%r%r
         To get to a place, +taxi <abbreviation>%r
         [repeat(-,72)]

&CMD-DIR-SPECIFIC #1516=
   $+dir *:
      @switch [get(#1498/LOC-%0)]=
         ?*,
            {
               @pemit %#=
                  [ulocal(#1498/fn-display-dir-entry-long,LOC-%0)]%r
            },
         {
            @pemit %#=Sorry, I don't know that place.  Try +dir for a list.
         }

&FN-DISPLAY-DIR-ENTRY #1498=
   %r%t[ljust(after(%0,LOC-),10)][after(get(#1498/%0),|)]

&FN-DISPLAY-DIR-ENTRY-LONG #1498=
   [after(get(#1498/%0),|)] ([ucstr(after(%0,LOC-))]) is at [name(before(get(#1498/%0),|))].